For Beginner

How to Speed Up Slow Music/Video Folder Views in Windows 11 Explorer

Overview

In Windows Explorer, folders can be set to different types like General, Music, Videos, etc.
However, when there are many files, especially in Music or Video folders, the folder view can become slow and hard to use. This is because Windows tries to read metadata such as artist info, album art, camera details, and more.

This guide introduces a setting that hides this metadata to speed up folder display.
Tested on Windows 11, this article explains two methods and some notes for troubleshooting.

For beginners: How to change music folder display items all at once in GUI

This method allows you to hide unnecessary metadata fields in Music or Video folders and apply the same view settings to all similar folders.

By default, Music, Video, and Pictures folders load a lot of metadata (from ID3 tags, RIFF chunks, EXIF, embedded thumbnails, etc.), which causes slow folder loading every time you open them.

The following steps show how to remove metadata display items and speed up folder view. The changes can be applied to all folders of the same type (e.g., all Music folders).

Steps (Example: Music Folder)
You can use the same steps for Video folders as well.

  1. Open the Music folder.
  2. Click “View” in the toolbar and select “Details.”
  3. By default, Music folders show columns like Track, Title, Contributing Artist, and Album.
    Right-click on the column headers and uncheck these items to hide them.
  4. Add simpler columns like Type, Size, and Date Modified instead.
    These are standard fields used in General or Document folders and do not rely on metadata.
  5. Click the three dots (...) in the toolbar, then select Options.
  6. In Folder Options, go to the View tab.
  7. Click Apply to Folders.
    • This applies the current folder’s display settings to all folders of the same type (in this case, Music).

Notes

  • The folder type remains set to Music.
  • Other Music folders will now use the same display settings.
  • Newly created folders under the Music category will also use this display setting.
  • If you copy a Music folder from another PC, you may need to repeat these steps. This is because a desktop.ini file may override the display settings.

For those who can use commands: How to change folder settings at once in the registry

This method adds a registry entry to apply folder settings.
Instead of manually editing the registry using the Registry Editor—which can be risky and hard to undo—this method uses a command that is safer and easier to manage.

The registry keys added by this command are relatively low risk.
Even beginners can try this method safely as long as they type the command correctly.
If there’s a mistake, it’s easy to delete or fix the entry.

When you run this command, all folders (regardless of type) will be treated as General folders, which do not load extra metadata like music or video folders do.

To run the command, open Command Prompt or PowerShell as Administrator.
Then, copy and paste the command below to apply the setting.

Command to be set

BAT (Batchfile)
reg add "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags\AllFolders\Shell" /v FolderType /t REG_SZ /d NotSpecified

Command to delete a setting

BAT (Batchfile)
reg delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags\AllFolders\Shell" /v FolderType

The setting is not reflected!Registry, desktop.ini may be the cause!

⚠️ Note: This section is recommended only for intermediate to advanced Windows users.

Sometimes, even after applying the folder settings, the changes are not reflected.
This usually happens if individual folder settings have already been saved—either in the registry or in desktop.ini files inside each folder.

In such cases, you may need to reset the settings by:

  • Deleting certain registry keys
  • Removing the automatically generated desktop.ini files in each folder

When you customize a folder (via folder options or properties), Windows saves that setting either in the registry or in a desktop.ini file inside the folder.

Windows prioritizes the registry settings (BagMRU and Bags) over the desktop.ini files.
So to fully reset folder view behavior, you need to clear those registry entries first.

Even after deleting the registry keys, desktop.ini files will still remain.
To fully reset folder views, you may also want to delete desktop.ini files in bulk.

Command to Remove Folder View Settings from the Registry

(This resets all folder types to the system default)

After running the command to delete the registry entries, Windows Explorer will automatically rebuild the folder view settings when it restarts.

This is similar to the "Reset Folders" option in Folder Options, but the registry method can remove entries that the GUI cannot.Below, you'll find a script to delete desktop.ini files across folders.

BagMRU delete

BAT (Batchfile)
reg delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU"

Bags delete

BAT (Batchfile)
reg delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags"

Bat to delete desktop.ini in bulk
What this script does:
This sample script targets all subfolders inside the current user's Music folder, but it excludes the default desktop.ini file located directly in the root of the Music folder.

After execution, a log file is saved in the Music folder to record what was deleted.

You can change the folder being targeted by modifying the Root value in the script (e.g., replace Music with Videos to process the Videos folder instead).

BAT (Batchfile)
@echo off
setlocal enabledelayedexpansion

REM ─────────────────────────────────────────
REM Setting area
set "ROOT=%USERPROFILE%\Music"
set "LOGFILE=%ROOT%\desktop_ini_revert.log"
REM ─────────────────────────────────────────

REM logfile initialization
echo [%date% %time%] Desktop INI Restore Batch Start > "%LOGFILE%"

echo. >> "%LOGFILE%"
echo [%date% %time%] root folder: %ROOT% processing >> "%LOGFILE%"

REM Recursively loop through subfolders (excluding root itself)
for /R "%ROOT%" %%D in (.) do (
    if /I not "%%~fD"=="%ROOT%" (
        set "iniPath=%%~fD\desktop.ini"
        if exist "!iniPath!" (
            echo [%date% %time%] deletion: %%~fD\desktop.ini >> "%LOGFILE%"
            del /F /Q /A:HS "%%~fD\desktop.ini"
            attrib -s "%%~fD"
        ) else (
            echo [%date% %time%] Not present and skipped: %%~fD\desktop.ini >> "%LOGFILE%"
        )
    )
)

echo [%date% %time%] Desktop INI Delete Batch Complete >> "%LOGFILE%"

echo.
echo Created Log File： %LOGFILE%
pause

Create a desktop.ini file
Note:
This script was created as a personal reference and is not recommended for general use. It is only useful for very specific or advanced customization cases.

What this script does:
It creates a desktop.ini file in every subfolder of the specified Music folder.
The content of the desktop.ini file is minimal—only setting the folder type to Documents.

As with the delete script, a log file is saved in the Music folder.
You can change the target by editing the Root value (e.g., replace Music with Videos to target the Videos folder).

BAT (Batchfile)
@echo off
setlocal enabledelayedexpansion

REM ─────────────────────────────────────────
REM Setting area
set "ROOT=%USERPROFILE%\Music"
set "TYPE=Documents"
set "LOGFILE=%ROOT%\desktop_ini_deploy.log"
REM ─────────────────────────────────────────

REM logfile initialization
echo [%date% %time%] Desktop INI distribution batch started > "%LOGFILE%"

REM Create desktop.ini template in temporary
> "%TEMP%\_desktop.ini" (
  echo [ViewState]
  echo FolderType=%TYPE%
)

echo. >> "%LOGFILE%"
echo [%date% %time%] Root Folder: %ROOT%  >> "%LOGFILE%"

REM Recursively loop through subfolders (excluding root itself)
for /R "%ROOT%" %%D in (.) do (
    if /I not "%%~fD"=="%ROOT%" (
        set "iniPath=%%~fD\desktop.ini"
        if exist "!iniPath!" (
            echo [%date% %time%] Skip (with existing): %%~fD >> "%LOGFILE%"
        ) else (
            echo [%date% %time%] deployment: %%~fD >> "%LOGFILE%"
            copy /Y "%TEMP%\_desktop.ini" "%%~fD\desktop.ini" >nul
            attrib +s "%%~fD"
            attrib +h +s "%%~fD\desktop.ini"
        )
    )
)

REM temporary deletion
del "%TEMP%\_desktop.ini"

echo [%date% %time%] Desktop INI distribution batch completed >> "%LOGFILE%"
echo.
echo Created Log File： %LOGFILE%
pause